# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=uget
pkgver=2.2.3
_debver=$pkgver
_debrel=2
pkgrel=3
pkgdesc="GTK+ download manager featuring download classification and HTML import"
arch=('i686' 'x86_64')
license=('LGPL-2.1')
depends=('gtk' 'gstreamer' 'curl')
makedepends=('intltool' 'quilt')
optdepends=('aria2: alternative backend')
source=("https://downloads.sourceforge.net/urlget/${pkgname}-${pkgver}-1.tar.gz"
        "https://deb.debian.org/debian/pool/main/u/uget/uget_${_debver}-${_debrel}.debian.tar.xz"
        'uget-gtk.appdata.xml')
sha512sums=('a2359200486c60a79d53083f25c627d70f969880765e5c38897e7d35e94540c59e45f294dc10b0863ae812c449d232ad230cae90bb5e0ebded9bcabf2b4b7725'
            'c34992e0bd6c2bd056ccdb8927104e99d57a5cd6ff5bac0979d79d42d8e4bada7454b1b8bef04ed1c4a35175f44c9f1404dc2d3fa9286e24f17b82cbb3fa3e24'
            '8848199d9a23f97e9e201f30edc6ec79fda3e782e4d5deb0acf9be3aff2c4ce8fec4fb615dfc1cdecd04a64ef602500101e998c2997eef8b562e9ae8c7dc3c57')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --disable-notify \
    --disable-rss-notify
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 "$srcdir/uget-gtk.appdata.xml" -t "$pkgdir/usr/share/metainfo"
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}