# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=totem-pl-parser
pkgver=3.26.5
_debver=$pkgver
_debrel=5
pkgrel=1
pkgdesc="Simple GObject-based library to parse and save a host of playlist formats"
url='https://gitlab.gnome.org/GNOME/totem-pl-parser'
license=('LGPL-2')
arch=('i686' 'x86_64')
depends=('libarchive' 'libxml2')
makedepends=('gobject-introspection' 'meson' 'quilt')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/t/totem-pl-parser/totem-pl-parser_${pkgver}.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/t/totem-pl-parser/totem-pl-parser_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('ce110d92f60da328272a8135a57ba60785ea4bca1fde3703a734969e7ba5b382ef19dc3b8930a5641d8f8effabf627f7e9b2727ee94e69e6144e0f085079e14d'
            'b6e3f4e8b6e208e1c850e6ea55ae6623be3dd15617259f15f39476fe6b0063a43bbfb292083c98356ae51fde1594fbe293dc6bb6933030f49bb272fbaddf3ac5')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  # we won't and don't support AmazonAMZ, so disabling libgcrypt
  hyperbola-meson $pkgname-$pkgver build -D enable-gtk-doc=false -D enable-libgcrypt=no
  ninja -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
  install -Dm644 $pkgname-$pkgver/COPYING.LIB -t "$pkgdir/usr/share/licenses/$pkgname"
}