# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=tklib
pkgver=0.7+20210111
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Tklib specializes in utilities for GUI programming."
arch=('i686' 'x86_64')
url='https://core.tcl-lang.org/tklib/home'
license=('custom:BSD')
depends=('tk' 'tcllib')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/t/tklib/tklib_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/t/tklib/tklib_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('2880968247e0370eb56d3a804f1af5a6d03ec3785407650bd23aa3b7f0cdf799e170751330175f5f1666b90cf30249efa17d04da824a81de950ace784d10f84e'
            'a19f0362781b808697740f32f45705902c9282c10ef1033637954cb3009049e8bd6fb65aafa2901176fb012979e2147461988cd45337a6d4babcd41c72e34aa3')

prepare() {
  cd "Tk_Library_Source_Code"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "Tk_Library_Source_Code"
  ./configure --prefix=/usr
  make all
}

package() {
  cd "Tk_Library_Source_Code"
  make DESTDIR="$pkgdir" install
  install -Dm644 debian/copyright -t "$pkgdir/usr/share/licenses/$pkgname"
}