# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=timew
pkgver=1.4.2
_debver=$pkgver
_debrel=3
pkgrel=1
pkgdesc="Free and libre command line time tracking application"
arch=('i686' 'x86_64')
url='https://timewarrior.net/'
license=('Expat')
makedepends=('cmake' 'gcc-libs' 'quilt')
optdepends=('task: Taskwarrior integration'
            'python: Holiday refresh script')
install=$pkgname.install
source=("https://deb.debian.org/debian/pool/main/t/timew/timew_${pkgver}+ds.1.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/t/timew/timew_${_debver}+ds.1-${_debrel}.debian.tar.xz")
sha512sums=('7ab4f4cbffadd6b92eb5b5db5ccd5c96c587c57cf6e9cc8641f7943526ab0d6157bf9224df1e26b7336b8fda510435b89435c8db8b429e33a943bd21e1348a0f'
            '9087f84a017f112ac074bf5eed4c26b0083e4897986c5daf0ffd66c87579b11d01dcc4d2aa230dad4d3b77cab227e45ee3fe76b6c52e74df440f4fab94ab53e0')

prepare() {
  mv "timewarrior" "${pkgname}-${pkgver}"
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${pkgname}-${pkgver}"
  cmake -DCMAKE_BUILD_TYPE=release -DCMAKE_INSTALL_PREFIX=/usr .
  make
}


package() {
  cd "${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install

  # link the refresh holiday scripts in /usr/bin/ for user convenience.
  chmod 755 "${pkgdir}"/usr/share/doc/timewarrior/doc/holidays/refresh
  ln -s /usr/share/doc/timewarrior/doc/holidays/refresh "${pkgdir}"/usr/bin/timew-refresh-holidays

  # license
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
}