# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=teeworlds
pkgver=0.7.5
_debver=$pkgver
_debrel=2
pkgrel=3
pkgdesc="Fast-paced, free and libre multiplayer 2D shooter game"
arch=('i686' 'x86_64')
url='https://www.teeworlds.com'
license=('Simplified-BSD' 'Modified-BSD' 'zlib' 'CC-BY-SA-3.0' 'CC0-1.0')
depends=('alsa-lib' 'glu' 'sdl2' 'freetype2')
makedepends=('quilt' 'python' 'bam' 'mesa' 'graphicsmagick')
groups=('games')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/t/teeworlds/teeworlds_${pkgver}.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/t/teeworlds/teeworlds_${_debver}-${_debrel}.debian.tar.xz"
        "${pkgname}.desktop")
sha512sums=('f3c7898b884aba0a61d40e4f5bacc71b2ba3bfb16b876efead5d96e6aeebdb3289c2a8a503e6407a9ff19970b59307447e1e066b631970e294d84303cd74cc83'
            '970bbbb1ce5cbd9cc8d806b38267b59245875dddf2cb82668e98b05346ba0cf3b9389ed65ac7268cd58bcee90e0368b192619e1d09b3b213decc70c351cf181f'
            '525825152eaa60a1a050c60f86fe076e01c67382d62c6d140938ee524a7a722dbd041d5ed7036ffa9db00c771df6a2af1804caa9b07194b6f263d05954eddef8')

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/system-libs.patch || true
    rm -v debian/patches/set-data-dir.patch || true
    rm -v debian/patches/new-wavpack.patch || true

    quilt push -av
  fi

  gm convert +set date:create +set date:modify "./other/icons/${pkgname}.ico" "${srcdir}/${pkgname}.png"
}

build() {
  cd ${pkgname}-${pkgver}
  bam conf=release
}

package() {
  cd ${pkgname}-${pkgver}

  # install data files
  mkdir -p "${pkgdir}"/usr/share/games/${pkgname}/data

  # handling package-data and binaries
  cp -r build/output/data/* "${pkgdir}"/usr/share/games/${pkgname}/data
  cp -r data/{languages,maps} "${pkgdir}"/usr/share/games/${pkgname}/data
  install -Dm755 build/output/${pkgname} "${pkgdir}"/usr/games/${pkgname}
  install -Dm755 build/output/${pkgname}_srv "${pkgdir}"/usr/games/${pkgname}_srv

  install -Dm644 "${srcdir}"/${pkgname}.desktop "${pkgdir}"/usr/share/applications/${pkgname}.desktop
  install -Dm644 "${srcdir}"/${pkgname}.png "${pkgdir}"/usr/share/pixmaps/${pkgname}.png

  install -Dm644 debian/$pkgname{,-server}.6 -t "${pkgdir}"/usr/share/man/man6

  install -Dm644 license.txt debian/copyright -t "${pkgdir}"/usr/share/licenses/${pkgname}
}