# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=tcpdump
pkgver=4.99.3
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Powerful command-line packet analyzer"
url='https://www.tcpdump.org'
arch=('i686' 'x86_64')
license=('Modified-BSD')
depends=('libpcap' 'libcap-ng' 'libressl')
makedepends=('cmake' 'quilt')
source=("https://www.tcpdump.org/release/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/t/tcpdump/tcpdump_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('e1442e923d89f367cfe403dc460d0d46e19a241470d56b30b7a411bedd8d21a78c428f20ffe725cbb4fa5068f7dcc5c93d206e1a8d53feb9bccc6f0cda8bf0f9'
            '2e77ab6d0a3c089df1ff0a999c87ba1d17fcb0c6fcf6eacecf43be9d1bf366809cbfbb519f2d04b1b0b410be9b4dd58fa5e04e594e609af06801bd54b6429b44')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  if [ ${pkgver%.*} = ${_debver%.*} ]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cmake \
    -S ${pkgname}-${pkgver} \
    -B build \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE='None' \
    -Wno-dev
  make -C build
}

package() {
  make DESTDIR="${pkgdir}" install -C build
  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}