# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=tbb
pkgver=2020.3
_debver=2020.3
_debrel=1
pkgrel=1
pkgdesc='High level abstract threading library'
arch=('i686' 'x86_64')
url='https://www.threadingbuildingblocks.org/'
license=('Apache-2.0')
depends=('gcc-libs')
makedepends=('cmake' 'quilt')
conflicts=('intel-tbb')
provides=("intel-tbb=$pkgver")
replaces=('intel-tbb')
source=(https://github.com/oneapi-src/oneTBB/archive/v$pkgver/$pkgname-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/t/tbb/tbb_$_debver-$_debrel.debian.tar.xz)
sha512sums=('ea1ffd22c7234d715b8c46a4e51b40719c7a9b8837ab3166f1da5a2c6061167c2be2126b1d74fd361eec6975b8fce0df26829ca2e7af8029edbb52e40f23d630'
            '4d5739218e1352a6463dab5fbad2be4ec1e6817be4be86650edd406a2024a51e188efccc56623c0b3358960685e2d7b892eed0a50a3fb51cdc24a2d614215617')

prepare() {
  cd oneTBB-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd oneTBB-$pkgver
  make
}

package() {
  cd oneTBB-$pkgver
  install -Dm755 build/linux_*/*.so* -t "$pkgdir"/usr/lib
  install -d "$pkgdir"/usr/include
  cp -a include/tbb "$pkgdir"/usr/include
  cmake \
    -DINSTALL_DIR="$pkgdir"/usr/lib/cmake/TBB \
    -DSYSTEM_NAME=Linux -DTBB_VERSION_FILE="$pkgdir"/usr/include/tbb/tbb_stddef.h \
    -P cmake/tbb_config_installer.cmake
  install -Dm644 LICENSE -t \
    "$pkgdir"/usr/share/licenses/$pkgname
}