# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=sylpheed
pkgver=3.7.0
_debver=$pkgver
_debrel=8
pkgrel=1
pkgdesc="Lightweight and user-friendly e-mail client"
arch=('i686' 'x86_64')
url='https://sylpheed.sraoss.jp/en/'
license=('GPL-2' 'LGPL-2.1')
depends=('compface' 'gpgme' 'libnsl' 'libressl' 'gtk2')
makedepends=('quilt')
source=("https://sylpheed.sraoss.jp/${pkgname}/v${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2"
        "https://deb.debian.org/debian/pool/main/s/sylpheed/sylpheed_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('490837528bf7ba9d26994cd5fff00b6e5390a127419b9d0efd9fc25c38be1291d55c5b8daebdf5ca9d9159a51c938449e76212328f3eae40cc039db88cb5caa4'
            'a487c45e1bd4ce203d6e685ac35c75dcd8c570c2a1d9bfe1e5a3e17b044d57fe6467f1bcf585ddd472ef7749cdc8c7f4b39642eceae3555866ad59cc061c27d8')

prepare() {
  cd "$pkgname-$pkgver"
  if [ ${pkgver%.*} = ${_debver%.*} ]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/0010-use-enchant-2.patch || true

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd "$pkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --enable-maintainer-mode \
    --enable-ldap
  make

  # build Attachment-Tool Plug-in
  cd plugin/attachment_tool && make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install
  install -Dm644 COPYING{,.LIB} -t $pkgdir/usr/share/licenses/$pkgname

  # install Attachment-Tool Plug-in
  cd plugin/attachment_tool
  make DESTDIR="$pkgdir/" install-plugin
}