# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=subtitleripper
pkgver=0.5.2
pkgrel=1
pkgdesc="DVD subtitle to text converter"
arch=('i686' 'x86_64')
url='https://subtitleripper.sourceforge.net/'
license=('GPL-2')
depends=('netpbm')
source=("https://repo.hyperbola.info:50000/sources/${pkgname}/${pkgname}-${pkgver}.tar.gz"{,.sig})
sha512sums=('a061af59952f32c1396207e14a38080a84f8346e403f2b268cf20ef05b86bbc01819d1595e56c5d3ac010244148a5fd88f9a8c243adc1ea35fbc43854e638d93'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  # use netpbm instead of libppm
  sed -i 's/_HAVE_LIB_PPM_/_HAVE_NETPBM_/g' *
  sed -i 's|<ppm.h>|<netpbm/ppm.h>|g' *.[ch]
  sed -i 's/-lppm/-lnetpbm/' Makefile
  # quieten warnings about exit():
  sed -i '1s/^/#include <stdlib.h>/' subtitle2pgm.c
  # force use of getline to prevent aborted build:
  sed -i 's/DEFINES :=/DEFINES := -DHAVE_GETLINE/' Makefile
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  install -Dm755 {pgm2txt,srttool,subtitle2pgm,subtitle2vobsub,subtitleripper,vobsub2pgm} -t "$pkgdir/usr/bin"
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}