# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=strace
pkgver=5.10
_debver=5.10
_debrel=1
pkgrel=1
pkgdesc='A diagnostic, debugging and instructional userspace tracer'
arch=('i686' 'x86_64')
url='https://strace.io/'
license=('LGPL-2.1')
depends=('perl' 'libunwind')
makedepends=('quilt')
source=("https://github.com/strace/strace/releases/download/v$pkgver/strace-$pkgver.tar.xz"
        "https://deb.debian.org/debian/pool/main/s/strace/strace_$_debver-$_debrel.debian.tar.xz")
sha512sums=('1baa41b6d52f2e40e42a22850beee1ae278fafe712796694631898f06a7540d8f2c3fa70807e0062734f0976ebbd0824457c733ccda248f017c218387366ed48'
            '517ebd81ba10f311775ae951e21a1d72c795b7d205e7cbd6427febfb5d64c4070a58fe2c23e645900cebfbb6046862a02dcf6dc7b52db0b8f8af0e18d40a68e5')

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    rm -rf ./debian
    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver

  ./configure --prefix=/usr \
              --with-libunwind

  make
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}