# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=stella
pkgver=6.7
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Atari 2600 VCS emulator"
arch=('i686' 'x86_64')
url='https://stella-emu.github.io/'
license=('GPL-2')
depends=('sdl2' 'gtk-update-icon-cache')
makedepends=('glu' 'quilt')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/s/stella/stella_${pkgver}+dfsg.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/s/stella/stella_${_debver}+dfsg-${_debrel}.debian.tar.xz")
sha512sums=('146b44ef23ddc268f4384e5c5770d1e2ad99bbc32ba1c48b73644dcf3c1a4af0cee4685209a634f905e913f48618ecb742e8afd43ab44c355a688233d89b32ae'
            '757307b5f507c45987e8377ffb036f38ed70f29584b2f8b5d1bdeeca631d3c98392c56b24c60322eeb89e8e22b3f8ab2a9ea4b2f03e28a6e69f5e0d850b5b972')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    rm -rf ./debian
    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver

  ./configure --prefix=/usr

  make
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir" install
  install -Dm644 License.txt -t "${pkgdir}/usr/share/licenses/$pkgname"
}