# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=stegseek
pkgver=0.6
pkgrel=1
pkgdesc="Lightning fast steghide cracker"
arch=('i686' 'x86_64')
url="https://github.com/RickdeJager/stegseek"
license=('GPL-2')
depends=('mhash' 'libmcrypt' 'libjpeg' 'zlib')
makedepends=('cmake')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/RickdeJager/stegseek/archive/v${pkgver}.tar.gz"
        "fix-build-i686.patch")
sha512sums=('e55e1f63e02d70528bfe6ab15c313b3566749616fdbb22a7088d7abaf07a1bc79ae6d84bd65f89313980964bd2d42be9ba86007df09d7c3e90c779dc729789bf'
            'e23fc3476406716a017dc170f493adcd4ab5511779eab718a00340c8e7cc6f1a0024edf8306dc381848dcb9b9c4f8ec76d9e19bfa55abafd3cf23280237fbc99')

prepare() {
  cd "${pkgname}-${pkgver}"
  if [[ $CARCH = "i686" ]]; then
    patch -Np1 -i ${srcdir}/fix-build-i686.patch
  fi
}

build() {
  cmake -B build -S "${srcdir}/${pkgname}-${pkgver}" -DCMAKE_INSTALL_PREFIX=/usr
  make -C build
}

package() {
  cd "${srcdir}/build"
  make DESTDIR="${pkgdir}/" install
  install -Dm644 ${srcdir}/${pkgname}-${pkgver}/COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}