# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=spice
pkgver=0.14.3
_debver=$pkgver
_debrel=2.1
pkgrel=2
pkgdesc="SPICE server"
arch=('i686' 'x86_64')
url='https://www.spice-space.org'
license=('LGPL-2.1')
depends=('pixman' 'opus' 'libjpeg-turbo' 'glib2' 'libsasl' 'lz4')
makedepends=('meson' 'spice-protocol' 'quilt')
source=("https://www.spice-space.org/download/releases/${pkgname}-${pkgver}.tar.bz2"{,.sign}
        "https://deb.debian.org/debian/pool/main/s/spice/spice_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('9ecdc455ff25c71ac1fe6c576654b51efbfb860110bd6828065d23f7462d5c5cac772074d1a40f033386258d970b77275b2007bcfdffb23fdff2137154ea46e4'
            'SKIP'
            'b12443a3550a23cfc4baffd62729723d287759a9638fb2f93fe5075267acaafb23ae157a76203f8407f9d3707aadf0049bc5488317bb4902de31c82f165af2bb')
validpgpkeys=('206D3B352F566F3B0E6572E997D9123DE37A484F') # Victor Toso <me@victortoso.com>

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  hyperbola-meson "$pkgname-$pkgver" build -D gstreamer=no -D smartcard=disabled
  ninja -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
  install -Dm644 "$pkgname-$pkgver/COPYING" -t "$pkgdir/usr/share/licenses/$pkgname"
}