# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=speech-dispatcher
pkgname=('speech-dispatcher' 'libspeechd')
pkgver=0.10.2
_debver=$pkgver
_debrel=2
pkgrel=2
arch=('i686' 'x86_64')
pkgdesc="High-level device independent layer for speech synthesis interface"
url="http://www.freebsoft.org/speechd"
license=('GPL-3' 'FDL-1.2' 'LGPL-2.1')
makedepends=('intltool' 'espeak' 'libltdl' 'python-pyxdg' 'dotconf' 'libao' 'libsndfile' 'quilt')
source=("https://github.com/brailcom/speechd/releases/download/${pkgver}/speech-dispatcher-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/s/speech-dispatcher/speech-dispatcher_${_debver}-${_debrel}+deb11u2.debian.tar.xz")
sha512sums=('9af240d9a15062489c170440911e9d148d0d113a0f22211f1496e9754345a5d079e160962d666801322dc2efa1134f8b5e209c0183d93a1f0896705dc6011122'
            '860d8425efb64ce567b4e0ef6164fe1e2ca20c0832c4c44158d88d9ba6bbda97d693c33c23363eb0dbe58d08e834e241ac22bbe174065c935f222815eba102c7')

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/systemd-debian || true
    rm -v debian/patches/mbrola-paths || true

    quilt push -av
  fi

  # Disabled modules
  sed -i "s/cicero //g" configure.ac
  sed -i "s/sd_cicero//g" src/modules/Makefile.am
  sed -i "s/festival //g" configure.ac
  sed -i "s/sd_festival//g" src/modules/Makefile.am

  autoreconf -vfi
}

build() {
  cd ${pkgname}-${pkgver}

  ./configure --prefix=/usr \
    --enable-shared \
    --sysconfdir=/etc \
    --without-flite \
    --without-pulse
  make
}

package_speech-dispatcher() {
  depends=("libspeechd=$pkgver-$pkgrel" 'libltdl' 'python-pyxdg'
           'dotconf' 'libsndfile' 'libao' 'espeak')
  optdepends=('espeak: Speech output using ESpeak')
  backup=(etc/speech-dispatcher/clients/emacs.conf
  	  etc/speech-dispatcher/modules/ibmtts.conf
  	  etc/speech-dispatcher/modules/espeak.conf
  	  etc/speech-dispatcher/modules/espeak-ng.conf
  	  etc/speech-dispatcher/modules/swift-generic.conf
  	  etc/speech-dispatcher/modules/festival.conf
  	  etc/speech-dispatcher/modules/cicero.conf
  	  etc/speech-dispatcher/modules/espeak-mbrola-generic.conf
  	  etc/speech-dispatcher/modules/espeak-ng-mbrola-generic.conf
  	  etc/speech-dispatcher/modules/dtk-generic.conf
  	  etc/speech-dispatcher/modules/llia_phon-generic.conf
  	  etc/speech-dispatcher/modules/ivona.conf
  	  etc/speech-dispatcher/modules/epos-generic.conf
          etc/speech-dispatcher/modules/flite.conf
          etc/speech-dispatcher/speechd.conf)

  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install

  #install -Dm644 "${srcdir}"/speech-dispatcherd.service "${pkgdir}/usr/lib/systemd/system/speech-dispatcherd.service"
  install -d "${pkgdir}/var/log/speech-dispatcher"

  sed -i 's|includedir=.*|includedir=${prefix}/include/speech-dispatcher|g' "${pkgdir}/usr/lib/pkgconfig/speech-dispatcher.pc"

  mkdir -p "${srcdir}"/libspeechd/usr/lib
  mv "${pkgdir}"/usr/include "${srcdir}"/libspeechd/usr
  mv "${pkgdir}"/usr/lib/libspeechd*so* "${srcdir}"/libspeechd/usr/lib

  install -Dm644 ${srcdir}/${pkgbase}-${pkgver}/COPYING.GPL-3 -t "${pkgdir}/usr/share/licenses/$pkgname"
  install -Dm644 ${srcdir}/${pkgbase}-${pkgver}/debian/copyright -t "${pkgdir}/usr/share/licenses/$pkgname"
}

package_libspeechd() {
  mkdir -p "${pkgdir}"/usr/lib

  mv "${srcdir}"/libspeechd/usr/include "${pkgdir}"/usr
  mv "${srcdir}"/libspeechd/usr/lib/* "${pkgdir}"/usr/lib

  install -Dm644 ${srcdir}/${pkgbase}-${pkgver}/COPYING.LGPL -t "${pkgdir}/usr/share/licenses/$pkgname"
  install -Dm644 ${srcdir}/${pkgbase}-${pkgver}/debian/copyright -t "${pkgdir}/usr/share/licenses/$pkgname"
}