# Maintainer: Jesus E. <heckyel@riseup.net>

_realpkgname=smplayer
pkgname=$_realpkgname-legacy
pkgver=20.6.0
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Media player with built-in codecs that can play virtually all free and libre video and audio formats (legacy version)"
url='https://www.smplayer.info/'
arch=('i686' 'x86_64')
license=('GPL-2' 'Modified-BSD' 'Simplified-BSD')
depends=('glibc' 'qt-script' 'qt-base' 'mplayer' 'libx11' 'zlib' 'gcc-libs' 'hicolor-icon-theme')
makedepends=('qt-tools' 'quilt')
optdepends=('smplayer-themes: icon themes collection'
            'smplayer-skins: skin themes collection'
            'mpv-legacy: alternative multimedia engine')
source=(https://downloads.sourceforge.net/${_realpkgname}/${_realpkgname}-${pkgver}.tar.bz2
        https://deb.debian.org/debian/pool/main/s/smplayer/smplayer_${_debver}~ds0-${_debrel}.debian.tar.xz
        libre.patch
        remove-update-check.patch)
sha512sums=('2cf7b7abf44b301331a5389e1ca512bd41928724b412d8cf55d77cb5cde87a4fdb9038d77c31da14b548d38ebfadd461d588d60a6b6f13b1781b9b961e81637d'
            '88c544832c2da3b0b978fa6b99ef36cf3c3746e3324a31e2510a8a7feede08d01a6b171269754cf7223c49cc6128d588c49ab3997775f5820cbbd0c3d300cdf2'
            '31ff91c53b2ab7f9cee2fdd9a640b3562618986e391cefb9cc542765a0de177d64d0faad51af0967c66f7d7035fe6f468423f79191a6ec75d6d7d30aa346b3f4'
            '58df298a5582b9f8bd8bb333d1a86d4239693452c67e73aa817f8e0320ad5152abc6617a237d7521f462c5b9cbf3c8f850b4f5c157be56eb58e44f1376684d78')

prepare() {
  cd ${_realpkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/05-add-debian-hardening-flags.patch || true

    quilt push -av
  fi

  # make build reproducible, we compress ourselves
  sed '/gzip -9/d' -i Makefile

  # additional fixes for removal of dbus and non-free components / services / platforms
  patch -Np1 -i $srcdir/libre.patch

  # remove update check menu-entry
  patch -Np1 -i $srcdir/remove-update-check.patch

  # fix GNU/Linux name
  sed -i 's|Linux|GNU/Linux|' src/smplayer.cpp
}

build() {
  cd ${_realpkgname}-${pkgver}
  export CXXFLAGS="${CXXFLAGS} ${CPPFLAGS}"
  make PREFIX=/usr \
    DOC_PATH="\\\"/usr/share/doc/smplayer\\\"" \
    QMAKE_OPTS=DEFINES+=NO_DEBUG_ON_CONSOLE \
    CFLAGS_EXTRA="${CFLAGS} ${CPPFLAGS} ${LDFLAGS}"
}

package() {
  cd ${_realpkgname}-${pkgver}
  make DOC_PATH=/usr/share/doc/smplayer \
    DESTDIR="${pkgdir}" PREFIX=/usr -j1 install

  # licenses
  install -Dm644 Copying{,_BSD,_libmaia}.txt -t "${pkgdir}/usr/share/licenses/$pkgname"
}