# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=shtool
pkgver=2.0.8
_debver=2.0.8
_debrel=10
pkgrel=1
pkgdesc="GNU shtool is a compilation of small but very stable and portable shell scripts into a single shell tool."
url="http://www.gnu.org/software/shtool/"
license=('GPL-2')
arch=('i686' 'x86_64')
depends=('perl')
makedepends=('quilt')
source=(https://ftp.gnu.org/gnu/$pkgname/$pkgname-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/s/shtool/shtool_$_debver-$_debrel.debian.tar.xz)
sha512sums=('f0c9292e8d980323d587b70e582574ba1cfe3c26296a01d51a2068a7886e5b1f501e8c5dc37b5d4b0f7a34217c7ad7f6f3011969d9c2d65776fe66e8287c1758'
            '5bcb6e490087d5e601e6332e62dd84b599747d4f1ca4e3f4b8020c955bd788ca5b3f97f3e2138d5d8eca9134f5ad88886e6a5382897f915957d510ba632fb6a0')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}