# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=sh-roundup
_pkgname=roundup
pkgver=0.0.6
pkgrel=2
pkgdesc="A unit testing framework for POSIX shell"
arch=('any')
url='https://bmizerany.github.io/roundup/'
license=('Expat')
depends=('bash')
makedepends=('ruby-ronn-ng')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/bmizerany/$_pkgname/archive/v$pkgver.tar.gz"
        "makefile-fix.patch")
sha512sums=('a7a249d16467bd3835d555288ec6c3d84a36f2f7f2ae5da90e7624bc76a7741788499fd635d3001c086923914870392c23d765ca07ab7c97e58b9deec9989827'
            'f7dade356d74d66dac5ad049eaeac4c156cdedf8036f4a8b4924aeb84bb002452e79d685566da8e109857c7624a2f561885f03d3d89deeb3c39e09df3135e936')

prepare() {
  cd "$srcdir/$_pkgname-$pkgver"
  patch -i $srcdir/makefile-fix.patch Makefile
}

build() {
  cd "$srcdir/$_pkgname-$pkgver"
  ./configure \
    --prefix="$pkgdir"/usr
  make -j1 build man
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"
  make -j1 install install-man
  install -Dm644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
}