# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=searchmonkey
pkgver=0.8.3
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="A powerful GUI search utility for matching regex patterns"
arch=('i686' 'x86_64')
url='https://sourceforge.net/projects/searchmonkey/'
license=('LGPL-2.1')
depends=('gtk2' 'libzip' 'poppler-glib')
makedepends=('intltool' 'quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/s/searchmonkey/searchmonkey_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/s/searchmonkey/searchmonkey_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('b6919433bde1d8c325fa6ccb7222a4fefa02dd10f9c614b92b3984a9ce4e6acbe1cce2d2caba4ee1f829e34b55e9c45c2703a5cf32d87e1dd6beaecaef82d402'
            '294bfae7d19ffea3bbbbe3b817ee70e4c2cf94ae64842c9d8912dc6fc59bd88e545855ce208d20d478df97ab9e32cb6569886ee74dc8368c31a3f46d1dc9dd9c')

prepare() {
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${pkgname}-${pkgver}"
  CFLAGS=-Wno-error ./configure --prefix=/usr
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="$pkgdir/" install
  install -Dm644 COPYING.LESSER -t "$pkgdir/usr/share/licenses/$pkgname"
}