# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=sdl_gfx
pkgver=2.0.25
_debver=2.0.25
_debrel=11
pkgrel=1
pkgdesc="SDL graphics drawing primitives and other support functions"
url="https://www.ferzkopp.net/wordpress/2016/01/02/sdl_gfx-sdl2_gfx/"
arch=(i686 x86_64)
license=(zlib)
depends=(sdl)
makedepends=(quilt)
source=(https://www.ferzkopp.net/Software/SDL_gfx-2.0/SDL_gfx-${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/s/sdlgfx/sdlgfx_$_debver-$_debrel.debian.tar.xz)
sha512sums=('42a5d78fe1a9b644d329fb688ed6c98558f8dd0aa029a1a0d99b1c59f94859269e0aef8f9e420b8018b687d8eae151652890be3994775644e1d3a80ba7b6fe8c'
            '1b6ed8292858859e7f0e7687841e367b85850a6b85f2161ac161804a79e884738d619ae5b97307cd286c995aa7438641008b7e4241922e3cf9ab11253667baae')

prepare() {
  cd SDL_gfx-$pkgver
  if [[ $pkgver = $_debver ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd SDL_gfx-$pkgver
  ./configure --prefix=/usr \
    $([[ $CARCH == x86_64 ]] && echo --disable-mmx)
  make
}

package() {
  cd SDL_gfx-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
}