# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=sdl2_mixer
pkgver=2.0.4
_debver=2.0.4+dfsg1
_debrel=3
pkgrel=1
pkgdesc='A simple multi-channel audio mixer (Version 2)'
arch=('i686' 'x86_64')
url='http://www.libsdl.org/projects/SDL_mixer'
license=('zlib')
depends=('sdl2' 'libvorbis' 'libmodplug' 'mpg123' 'flac' 'opusfile')
makedepends=('fluidsynth' 'quilt')
optdepends=('fluidsynth: MIDI software synth, replaces built-in timidity')
source=("https://www.libsdl.org/projects/SDL_mixer/release/SDL2_mixer-${pkgver}.tar.gz"
        https://deb.debian.org/debian/pool/main/libs/libsdl2-mixer/libsdl2-mixer_$_debver-$_debrel.debian.tar.xz)
sha512sums=('98c56069640668aaececa63748de21fc8f243c7d06386c45c43d0ee472bbb2595ccda644d9886ce5b95c3a3dee3c0a96903cf9a89ddc18d38f041133470699a3'
            '86326996e91e5c00e19db7c4f81ca46540bb92e340432ba8b2cf9d2fae1faa901f504a9bc65ff6850795b599d5c83b29d8a70893473f3a7bcff690ca4d44561b')

prepare() {
  cd "${srcdir}/SDL2_mixer-${pkgver}/"

  sed -i "s|/etc/timidity|/etc/timidity++|g" timidity/options.h
  sed -i "s|/etc/timidity++.cfg|/etc/timidity++/timidity.cfg|g" timidity/options.h

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    rm -rf ./debian
    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/SDL2_mixer-${pkgver}/"

  ./configure --disable-static --prefix=/usr
  make
}

package() {
  cd "${srcdir}/SDL2_mixer-${pkgver}/"

  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
}