# Maintainer: Jesus E. <heckyel@riseup.net>

_gemname=mini_portile2
pkgname=ruby-mini_portile2
pkgver=2.8.1
pkgrel=1
pkgdesc="Simple autoconf builder for developers"
url='https://github.com/flavorjones/mini_portile'
arch=('any')
license=('Expat')
depends=('ruby')
options=('!emptydirs')
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/flavorjones/mini_portile/archive/v${pkgver}.tar.gz)
sha512sums=('5f0b5806deae6d4b4d5c0a74dccb3fd09bad46db235ea00f288f4a493b60b78d165892b41320658961ffb382bc533c594c9435e80dcf7369d767de9829606947')

prepare() {
  cd mini_portile-${pkgver}
  sed -r 's|~>|>=|g' -i ${_gemname}.gemspec # the comment say: dont care about rubys bla bla !
  sed 's|git ls-files -z|find -type f -print0|' -i ${_gemname}.gemspec
}

build() {
  cd mini_portile-${pkgver}
  gem build ${_gemname}.gemspec
}

package() {
  cd mini_portile-${pkgver}
  local _gemdir="$(gem env gemdir)"
  gem install --ignore-dependencies --no-user-install -i "${pkgdir}${_gemdir}" -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
  rm "${pkgdir}/${_gemdir}/cache/${_gemname}-${pkgver}.gem"
  install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
  install -Dm 644 README.md CHANGELOG.md -t "${pkgdir}/usr/share/doc/${pkgname}"
}