# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=rofi
pkgver=1.7.3
_debver=$pkgver
_debrel=0.1
pkgrel=2
pkgdesc="A window switcher, application launcher and dmenu replacement"
arch=('i686' 'x86_64')
url='https://github.com/DaveDavenport/rofi'
license=('Expat')
depends=('libxdg-basedir' 'startup-notification' 'libxkbcommon-x11'
         'xcb-util-wm' 'xcb-util-xrm' 'xcb-util-cursor' 'librsvg-legacy')
makedepends=('quilt' 'check')
optdepends=('i3-wm: use as a window switcher')
source=("https://github.com/DaveDavenport/rofi/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/r/rofi/rofi_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('bba9ee25c7ff2168370ad1fd21a2286706f9db1efccdab84c55abd3bfa822ed10d23128388c69c964e81b2c51e1a95b3a3c7ca503a4564d0bdb3a993d8a9553d'
            '2dafa1191a92f9c112b0906de98628332a489123a29ab75077f8faa78d366c5ec0aa8d4dd49d35680f35b6c579572ac5dab959664a0abf378ef33a1449d798b7')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -i
}

build() {
  cd "$pkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc
  make
}

package() {
  cd "$pkgname-$pkgver"
  make install install-man DESTDIR="$pkgdir"

  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
  install -dm755 "$pkgdir/usr/share/doc/$pkgname/examples"
  install -Dm755 Examples/*.sh "$pkgdir/usr/share/doc/$pkgname/examples"
}