# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=rhash
pkgver=1.4.1
_debver=1.4.1
_debrel=2
pkgrel=1
pkgdesc='Utility for verifying hash sums of files'
url='https://github.com/rhash/RHash'
license=('custom:BSD-Zero-Clause')
arch=('i686' 'x86_64')
depends=('glibc')
makedepends=('quilt')
backup=('etc/rhashrc')
source=(rhash-$pkgver.tar.gz::https://github.com/rhash/RHash/archive/v$pkgver.tar.gz
        rhash-$pkgver.tar.gz.asc::https://github.com/rhash/RHash/releases/download/v$pkgver/v$pkgver.tar.gz.asc
        https://deb.debian.org/debian/pool/main/r/rhash/rhash_$_debver-$_debrel.debian.tar.xz)
sha512sums=('30bbef7ce7815ee4ac062c537206a0b895845f61de4b1fdc0c0494f66284d9f3c1b06f812ea913fa35a3342d230d25d0986a1db644c7b4464bc1185997beb638'
            'SKIP'
            '2322d426734e3359e355620bf5f74321f335c94c2786971f08bed036f46abdcaaff66bdcec7da116ecf89bfb59717bf3a322ff1eaf546b5651a5758748e59c0e')
validpgpkeys=('2875F6B1C2D27A4F0C8AF60B2A714497E37363AE')

prepare() {
  cd RHash-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd RHash-$pkgver

  ./configure --prefix=/usr --sysconfdir=/etc --extra-cflags="$CFLAGS" --extra-ldflags="$LDFLAGS"
  make
}

check() {
  cd RHash-$pkgver

  make test test-lib
}

package() {
  cd RHash-$pkgver

  # program
  make DESTDIR="$pkgdir" install

  # library, since the makefiles are still broken
  make -C librhash DESTDIR="$pkgdir" install-lib-headers install-lib-shared install-so-link

  # license
  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/rhash/COPYING
}