# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=redshift
pkgver=1.12
_debver=1.12
_debrel=4.2
pkgrel=1
pkgdesc="Adjusts the color temperature of your screen according to your surroundings."
arch=('i686' 'x86_64')
url='http://jonls.dk/redshift/'
license=('GPL-3')
depends=('libdrm' 'libxcb' 'libxxf86vm')
optdepends=('python-pygobject: for redshift-gtk'
            'python-pyxdg: for redshift-gtk'
            'gtk: for redshift-gtk')
makedepends=('intltool' 'gettext-tiny' 'python' 'quilt' 'automake-1.15' 'gtk-update-icon-cache')
source=("https://github.com/jonls/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/r/redshift/redshift_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('225e222e5f2c55be4571094ccaf02a92e162dfc35fd0fe504084e21e358b888a72f9992f9f9edaf1d496eb673af74a0d825ae5cf6ef7f0f1ab51d32419722c32'
            '219152ec0a1ae128a9fb0a9732e007eb96f8331fec5ea1666fd9ff2a1e9fb4b2d94d60410515db0dae664139c4f13837e1c11fb384af8f2709907d631b9beb14')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure \
    --prefix=/usr \
    --enable-drm \
    --enable-randr \
    --enable-vidmode \
    --disable-geoclue2
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}