# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=radare2
pkgver=5.9.4
pkgrel=1
pkgdesc="Free and libre tools to disasm, debug, analyze and manipulate binary files"
url='https://radare.org'
arch=('i686' 'x86_64')
license=('GPL-3' 'LGPL-3')
depends=('sh' 'capstone' 'libressl' 'libzip' 'zlib' 'lz4' 'xxhash' 'file' 'libuv')
makedepends=('meson')
options=('!emptydirs')
source=("https://github.com/radare/radare2/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha512sums=('51d42b6d98027d3f3d85570e79ea18a8f220c145e3451fd10d82eea1a0542648f83447bb6cb6f5bbf76241677a2412bf064ffbade75e69b486c6148543aa4b0f')

build() {
  cd ${pkgname}-${pkgver}
  touch libr/config.mk
  hyperbola-meson build \
    -D use_sys_capstone=true \
    -D use_capstone_version=v5 \
    -D use_sys_magic=true \
    -D use_sys_zip=true \
    -D use_sys_zlib=true \
    -D use_sys_lz4=true \
    -D use_sys_xxhash=true \
    -D use_sys_openssl=true \
    -D use_libuv=true \
    -D use_webui=false \
    -D want_threads=false

  ninja -C build
}

package() {
  cd ${pkgname}-${pkgver}
  DESTDIR="${pkgdir}" ninja -C build install
  cp -r doc/* "${pkgdir}/usr/share/doc/radare2"
  ln -s /usr/share/man/man1/radare2.1.gz "${pkgdir}/usr/share/man/man1/r2.1.gz"
  install -Dm 644 COPYING{,.LESSER} -t "${pkgdir}/usr/share/licenses/${pkgname}"
}