# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=qtpass
pkgver=1.3.2
_debver=$pkgver
_debrel=4
pkgrel=3
pkgdesc="A multi-platform GUI for password-store"
url='https://qtpass.org/'
license=('GPL-3')
arch=('i686' 'x86_64')
depends=('qt-base' 'password-store' 'pwgen')
makedepends=('qt-tools' 'qt-svg' 'quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/IJHack/${pkgname}/archive/v${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/q/qtpass/qtpass_$_debver-$_debrel.debian.tar.xz")
sha512sums=('9026f74f6ff75fcef2f6a0862484a2a1eaed1370edd0659e8b4d20039affe846e0da3a0a26a804563813bc678638ab67fa516441208e70c7e9de9b2eda876a10'
            'cadadec78f4bc5553c2b40add8dd5bd8272f0a5edb18a904e8c84962a839c92f4f7fe59209d1a4098a10da4fa06b3b86768acd4ed14dc355c5f52269e306d151')

prepare() {
  cd "${srcdir}/QtPass-${pkgver}"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  sed -i 's|qtpass-icon|qtpass|' ${pkgname}.desktop
}

build() {
  cd "${srcdir}/QtPass-${pkgver}"

  qmake-qt5
  make
}

package() {
  cd "${srcdir}/QtPass-${pkgver}"

  install -Dm755 main/qtpass "${pkgdir}/usr/bin/${pkgname}"
  install -Dm644 artwork/icon.png "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
  install -Dm644 ${pkgname}.desktop "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  install -Dm644 ${pkgname}.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
}