# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=qt-webchannel
_qtver=5.15.2
pkgver=${_qtver/-/}
_debver=5.15.2
_debrel=2
pkgrel=1
arch=('i686' 'x86_64')
url='https://www.qt.io'
license=('LGPL-3')
pkgdesc='Provides access to QObject or QML objects from HTML clients for seamless integration of Qt applications with HTML/JavaScript clients'
depends=('qt-declarative')
makedepends=('quilt')
groups=('qt')
replaces=('qt5-webchannel')
conflicts=('qt5-webchannel')
provides=('qt5-webchannel')
_pkgfqn="${pkgname/-/}-everywhere-src-${_qtver}"
source=("https://download.qt.io/official_releases/qt/${pkgver%.*}/${_qtver}/submodules/${_pkgfqn}.tar.xz"
        "https://deb.debian.org/debian/pool/main/q/qtwebchannel-opensource-src/qtwebchannel-opensource-src_$_debver-$_debrel.debian.tar.xz")
sha512sums=('7ac5e372695616863d247c5a61e5763a3934b58165e35c43da5ef1797d80005aa3d6eb258931ae7ee2b1f6a6fa743635ac4678c9cfe375cefa76e74cc81d095b'
            'abec8d52f735242df69c1759f5883c16d1807c7a9d78f8df392a5326d7c4061b4d6f290ea59a21f90f1a23ebe2ff34743efa0fd9d7c0a9cdb4d3a634b0cb995e')

prepare() {
  mkdir -p build

  cd ${_pkgfqn}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd build

  qmake ../${_pkgfqn}
  make
}

package() {
  cd build
  make INSTALL_ROOT="$pkgdir" install

  # Drop QMAKE_PRL_BUILD_DIR because reference the build dir
  find "$pkgdir/usr/lib" -type f -name '*.prl' \
    -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;

  # Install license
  install -D -m644 "${srcdir}"/${_pkgfqn}/LICENSE.LGPL3 "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE.LGPL3
}