# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=qt-translations
_pkgbasename=qttranslations
_qtver=5.15.2
pkgver=${_qtver/-/}
pkgrel=1
arch=('any')
url='https://www.qt.io'
license=('custom:GPL-3+Qt-Company-GPL-Exception-1.0')
pkgdesc="A cross-platform application and UI framework (Translations)"
depends=('qt-base')
makedepends=('qt-tools')
groups=('qt')
_pkgfqn="${_pkgbasename/5-/}-everywhere-src-${_qtver}"
source=("https://download.qt.io/official_releases/qt/${pkgver%.*}/${_qtver}/submodules/${_pkgfqn}.tar.xz")
sha512sums=('483b5d919f43c96a032e610cf6316989e7b859ab177cb2f7cb9bb10ebcddf8c9be8e04ff12db38a317c618d13f88455a4d434c7a1133f453882da4e026dd8cbe')

prepare() {
  mkdir -p build
}

build() {
  cd build

  qmake ../${_pkgfqn}
  make
}

package() {
  cd build
  make INSTALL_ROOT="$pkgdir" install

  # remove unfree parts, we don't support webengine and websockets
  rm "${pkgdir}"/usr/share/qt/translations/qtwebengine*.qm
  rm "${pkgdir}"/usr/share/qt/translations/qtwebsockets*.qm

  # install license
  install -D -m644 "${srcdir}"/${_pkgfqn}/LICENSE.GPL3-EXCEPT -t "${pkgdir}"/usr/share/licenses/${pkgname}
}