# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=qt-tools
_qtver=5.15.2
pkgver=${_qtver/-/}
pkgrel=5
arch=('i686' 'x86_64')
url='https://www.qt.io'
license=('LGPL-3')
pkgdesc="A cross-platform application and UI framework (Development Tools, QtHelp)"
depends=('qt-base' 'hicolor-icon-theme')
makedepends=('qt-declarative' 'clang' 'qt-webkit')
optdepends=('clang: for qdoc' 'qt-webkit: for Qt Assistant')
groups=('qt')
replaces=('qt5-tools')
conflicts=('qt5-tools' 'qtchooser')
provides=('qt5-tools')
_pkgfqn="${pkgname/-/}-everywhere-src-${_qtver}"
source=("https://download.qt.io/official_releases/qt/${pkgver%.*}/${_qtver}/submodules/${_pkgfqn}.tar.xz"
        {assistant,designer,linguist}.desktop)
sha512sums=('3bd32a302af6e81cd5d4eb07d60c5ef233f1ca7af1aae180c933ac28fafffce28c6c868eb032108747937ea951d6d4f0df5516841bc65d22c529207147533a8b'
            '7f2fdf6cb3faaefc92bd9489cf23a340a84b8af6aa25b23dd677e7951c125aeed23c8d2de36516ac847c057db3ed1835016b872934683abbde272718192a174d'
            '7c7d3c8a8616f197c742228435a4e0bc414a79ee68481c850dbca4534e43abd85bda1053e2111a7c57fe0007e8e3d57f78c410e25517eb849032d53e1c061496'
            '2ebb7c14f49b604f23335fcdc9136ae720d1981c3cb60f4197800bf2d18daee237616a192fa6ccf96afb8e1e5fe01dbb231ba4d5954b93b015e336e8da5ca0ef')

prepare() {
  mkdir -p build
}

build() {
  cd build

  qmake ../${_pkgfqn}
  make
}

package() {
  cd build
  make INSTALL_ROOT="${pkgdir}" install

  cd ../${_pkgfqn}
  # install missing icons and desktop files
  for icon in src/linguist/linguist/images/icons/linguist-*-32.png ; do
    size=$(echo $(basename ${icon}) | cut -d- -f2)
    install -p -D -m644 ${icon} \
      "${pkgdir}/usr/share/icons/hicolor/${size}x${size}/apps/linguist.png"
  done

  install -D -m644 src/assistant/assistant/images/assistant.png \
    "${pkgdir}/usr/share/icons/hicolor/32x32/apps/assistant.png"
  install -D -m644 src/assistant/assistant/images/assistant-128.png \
    "${pkgdir}/usr/share/icons/hicolor/128x128/apps/assistant.png"
  install -D -m644 src/designer/src/designer/images/designer.png \
    "${pkgdir}/usr/share/icons/hicolor/128x128/apps/QtProject-designer.png"
  install -d "${pkgdir}/usr/share/applications"
  install -m644 "${srcdir}"/{linguist,designer,assistant}.desktop \
    "${pkgdir}/usr/share/applications/"

  # Symlinks for backwards compatibility
  for b in "${pkgdir}"/usr/bin/*; do
    ln -s $(basename $b) "${pkgdir}"/usr/bin/$(basename $b)-qt5
  done

  # Drop QMAKE_PRL_BUILD_DIR because reference the build dir
  find "${pkgdir}/usr/lib" -type f -name '*.prl' \
    -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;

  # Install license
  install -D -m644 "${srcdir}"/${_pkgfqn}/LICENSE.LGPL3 "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE.LGPL3
}