# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=qt-svg
_qtver=5.15.2
pkgver=${_qtver/-/}
_debver=5.15.2
_debrel=3
pkgrel=1
arch=('i686' 'x86_64')
url='https://www.qt.io'
license=('LGPL-3')
pkgdesc='Classes for displaying the contents of SVG files'
depends=('qt-base')
makedepends=('quilt')
groups=('qt')
replaces=('qt5-svg')
conflicts=('qt5-svg')
provides=('qt5-svg')
_pkgfqn="${pkgname/-/}-everywhere-src-${_qtver}"
source=("https://download.qt.io/official_releases/qt/${pkgver%.*}/${_qtver}/submodules/${_pkgfqn}.tar.xz"
        "https://deb.debian.org/debian/pool/main/q/qtsvg-opensource-src/qtsvg-opensource-src_$_debver-$_debrel.debian.tar.xz")
sha512sums=('101e9c8fc05b1bb9c4e869564bff8e5723dd35f0ef557185e56e9dc12fdce74c531522c9642cdff639900eccf7ed0e04bfa48142741259697dded990fb481730'
            'a0822c389091a6464b6270bb3f1578a718c70603f66a6cdb78989e157b7fd6e412f9cb83bbaf52d43d3613f3ce9146ef84e36bf4807c54363e70824af56861cd')

prepare() {
  mkdir -p build

  cd ${_pkgfqn}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd build

  qmake ../${_pkgfqn}
  make
}

package() {
  cd build
  make INSTALL_ROOT="$pkgdir" install

  # Drop QMAKE_PRL_BUILD_DIR because reference the build dir
  find "$pkgdir/usr/lib" -type f -name '*.prl' \
    -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;

  # Install license
  install -D -m644 "${srcdir}"/${_pkgfqn}/LICENSE.LGPL3 "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE.LGPL3
}