# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=qt-base
pkgname=(qt-base qt-xcb-private-headers)
_qtver=5.15.2
pkgver=${_qtver/-/}
_debver=$pkgver
_debrel=9
pkgrel=9
arch=('i686' 'x86_64')
url='https://www.qt.io'
license=('LGPL-3')
pkgdesc="A cross-platform application and UI framework"
depends=('libjpeg-turbo' 'xcb-util-keysyms' 'xcb-util-renderutil' 'mesa-libgl' 'fontconfig' 'xdg-utils'
         'shared-mime-info' 'xcb-util-wm' 'libxrender' 'libxi' 'sqlite' 'xcb-util-image' 'mesa'
         'tslib' 'libxkbcommon-x11' 'libproxy' 'libcups' 'md4c' 'pcre2' 'harfbuzz')
makedepends=('sqlite' 'unixodbc' 'postgresql-libs' 'alsa-lib' 'gst-plugins-base-libs'
             'gtk' 'cups' 'quilt')
optdepends=('qt-svg: to use SVG icon themes'
            'postgresql-libs: PostgreSQL driver'
            'unixodbc: ODBC driver'
            'gtk: GTK platform plugin'
            'perl: for fixqt4headers and syncqt')
replaces=('qt5-base')
conflicts=('qt5-base' 'qtchooser')
provides=('qt5-base')
groups=('qt')
_pkgfqn="${pkgbase/-/}-everywhere-src-${_qtver}"
source=("https://download.qt.io/official_releases/qt/${pkgver%.*}/${_qtver}/submodules/${_pkgfqn}.tar.xz"
        "https://deb.debian.org/debian/pool/main/q/qtbase-opensource-src/qtbase-opensource-src_${_debver}+dfsg-${_debrel}+deb11u1.debian.tar.xz"
        "qt-base-cflags.patch"
        "kdebug-428095.patch"
        "qtnetwork-5.15.0-libressl.patch"
        "CVE-2024-39936.patch")
sha512sums=('a549bfaf867d746ff744ab224eb65ac1bdcdac7e8457dfa379941b2b225a90442fcfc1e1175b9afb1f169468f8130b7ab917c67be67156520a4bfb5c92d304f9'
            'e4d4210b222b6722c3b97d7139c6ddf812e8022454a20d677e1df60d1ec472079dfc0fc5805c81059b1bdb26e323b358ec7ec57fb24b972d2ce84e55d40b936e'
            'fa3dddfe42b7f0ade45bd0530badfc3a3800adbd3798bd814597527713c9fe360a242f7cf39312f4cc3c88e9bd7aba233bd6674c0fc78e694a1fd868474c4240'
            'afc8c44cb2fdb1b07b8e88bda102791d4f807a00acc60aad98114b5a5b78336b4e6aeff59fa2795f3f83f196635d034c571859dab7c7c0443a913012944a45a7'
            '1f249256ab94f72d667bc703ae668e0e7c0671ebd464a3800c9dd2121637438de7c2cd9a72a45610ab4ad584103c7261e237facc114b142dcec0c38930ce8975'
            '51f378c6751ec6b24c5afac4eaa9a6f9b54680b53610e3db14d42c931034382e875316e9c25a8b04d0e36d08deef614fd2c8dc4cabac5de9d718cf0255e3020c')

prepare() {
  cd ${_pkgfqn}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/armv4.diff || true
    rm -v debian/patches/gnukfreebsd.diff || true
    rm -v debian/patches/gnukfreebsd_linker_warnings.diff || true

    quilt push -av
  fi

  patch -p1 -i ${srcdir}/qt-base-cflags.patch # Use system CFLAGS
  patch -p1 -i ${srcdir}/kdebug-428095.patch # Fix black border on some menus with Breeze
  patch -p1 -i ${srcdir}/qtnetwork-5.15.0-libressl.patch # Add LibreSSL support
  patch -p1 -i ${srcdir}/CVE-2024-39936.patch # Fix CVE-2024-39936
}

build() {
  cd ${_pkgfqn}

  # Work around SSLv3_{client,server}_method missing in LibreSSL
  CFLAGS+=" -DOPENSSL_NO_PSK -DOPENSSL_NO_NEXTPROTONEG"
  CXXFLAGS+=" -Wno-deprecated-declarations -Wno-class-memaccess -Wno-packed-not-aligned"

  OPENSSL_LIBS='-lssl -lcrypto'

  [[ "${CARCH}" = "i686" ]] && SSE2="-no-sse2"

  ./configure -confirm-license -opensource -v \
    -prefix /usr \
    -docdir /usr/share/doc/qt \
    -headerdir /usr/include/qt \
    -archdatadir /usr/lib/qt \
    -datadir /usr/share/qt \
    -sysconfdir /etc/xdg \
    -examplesdir /usr/share/doc/qt/examples \
    -plugin-sql-{psql,sqlite} \
    -system-sqlite \
    -openssl-linked \
    -no-dtls \
    -nomake examples \
    -no-rpath \
    -no-dbus \
    -system-harfbuzz \
    -syslog \
    -no-mimetype-database \
    -no-use-gold-linker \
    -reduce-relocations \
    -no-strip ${SSE2} \
    -no-egl \
    -no-angle \
    -no-zstd \
    -opengl desktop \
    -no-vulkan \
    -qt-doubleconversion \
    -system-libpng \
    -system-libmd4c \
    -system-libjpeg \
    -system-pcre \
    -system-zlib \
    -system-freetype
  make
}

package_qt-base() {
  pkgdesc='A cross-platform application and UI framework'

  cd ${_pkgfqn}
  make INSTALL_ROOT="${pkgdir}" install

  # Install license
  install -D -m644 "${srcdir}"/${_pkgfqn}/LICENSE.LGPL3 "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE.LGPL3

  # Drop QMAKE_PRL_BUILD_DIR because reference the build dir
  find "${pkgdir}/usr/lib" -type f -name '*.prl' \
    -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;

  # Fix wrong qmake path in pri file
  sed -i "s|${srcdir}/${_pkgfqn}|/usr|" \
    "${pkgdir}"/usr/lib/qt/mkspecs/modules/qt_lib_bootstrap_private.pri

  # Symlinks for backwards compatibility
  for b in "${pkgdir}"/usr/bin/*; do
    ln -s $(basename $b) "${pkgdir}"/usr/bin/$(basename $b)-qt5
  done
}

package_qt-xcb-private-headers() {
  pkgdesc='Private headers for Qt Xcb'
  depends=("qt-base=$pkgver")
  optdepends=()
  groups=()
  replaces=('qt5-xcb-private-headers')
  conflicts=('qt5-xcb-private-headers')
  provides=('qt5-xcb-private-headers')

  cd ${_pkgfqn}
  install -d -m755 "$pkgdir"/usr/include/qtxcb-private
  cp -r src/plugins/platforms/xcb/*.h "$pkgdir"/usr/include/qtxcb-private/

  # Install license
  install -D -m644 "${srcdir}"/${_pkgfqn}/LICENSE.LGPL3 "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE.LGPL3
}