# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=qscintilla
pkgver=2.11.6
_debver=$pkgver
_debrel=2
pkgrel=3
pkgdesc="A port to Qt of Neil Hodgson's Scintilla C++ editor class"
license=('GPL-3')
arch=('i686' 'x86_64')
url='https://www.riverbankcomputing.com/software/qscintilla/intro'
depends=('qt-base')
makedepends=('qt-tools' 'quilt')
source=("https://www.riverbankcomputing.com/static/Downloads/QScintilla/$pkgver/QScintilla-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/q/qscintilla2/qscintilla2_${_debver}+dfsg-${_debrel}.debian.tar.xz")
sha512sums=('8055d72a40f9f5a7d45c6592055c1b8eb5e5c50ce9e51673babd5e567c769d60c64d244ba5a7def5731a3120099e9528d01ed94327a06bb56ae2fa2e5e37b198'
            '471c8edb3630985567d55fe7975624df19942e1834a8f95d469ceb2389ad6a8af948eab09b25814f9b60c20e3c4a97bc464c0fd5378dca7f8e4d8bd2a0fced29')

prepare() {
  cd QScintilla-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  export QMAKEFEATURES=${srcdir}/QScintilla-$pkgver/Qt4Qt5/features/

  cd QScintilla-$pkgver/Qt4Qt5
  qmake-qt5
  make

  cd ../designer-Qt4Qt5
  qmake-qt5 INCLUDEPATH+=../Qt4Qt5 QMAKE_LIBDIR+=../Qt4Qt5
  make
}

package() {
  cd QScintilla-${pkgver}/Qt4Qt5
  make DESTDIR="${pkgdir}" INSTALL_ROOT="${pkgdir}" install

  cd ../designer-Qt4Qt5
  make DESTDIR="${pkgdir}" INSTALL_ROOT="${pkgdir}" install
  install -Dm644 $srcdir/QScintilla-$pkgver/LICENSE -t $pkgdir/usr/share/licenses/$pkgname
}