# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=qiv
pkgver=2.3.2
_debver=2.3.2
_debrel=2
pkgrel=1
pkgdesc='Quick Image Viewer (qiv) is a very small and fast GDK/Imlib image viewer'
arch=('i686' 'x86_64')
url='https://spiegl.de/qiv/'
license=('GPL-2')
depends=('file' 'gtk2' 'imlib2' 'libexif' 'lcms2' 'desktop-file-utils')
makedepends=('quilt')
source=(https://spiegl.de/qiv/download/$pkgname-$pkgver.tgz
        https://deb.debian.org/debian/pool/main/q/qiv/qiv_$_debver-$_debrel.debian.tar.xz)
sha512sums=('c4636591f79e8e4c13807433a4101a461e614439e497a5637b958bd9d0937b04515854483d4060d9b1004d6c6060b437d634fdbe491eb0747a660ba65240472d'
            'c8e3540c58ac15cd262bc89e81ee63974607476fc789e7b370c8b2815f86cda14b18364d3795bfdca3b4180a785dfec0c9c5af80bad4bc497e068083b3b2777c')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    rm -rf ./debian
    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  sed -i "s|^PREFIX = .*|PREFIX = /usr|" Makefile
  sed -i "s|\./qiv|echo &|" Makefile  # nuke test
  sed -i "s|)/man/|)/share/man/|" Makefile
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  sed -i "s|^PREFIX = .*|PREFIX = $pkgdir/usr|" Makefile
  make install

  install -D -m 0644 README "$pkgdir/usr/share/doc/qiv/README"
  install -d "$pkgdir/usr/share/doc/qiv/contrib"
  cp contrib/* "$pkgdir/usr/share/doc/qiv/contrib"
  install -Dm644 README.COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}