# Maintainer: Jesus E. <heckyel@riseup.net>

_pkgname=zope.event
pkgbase=python-zope-event
pkgname=('python-zope-event' 'tauthon-zope-event')
pkgver=4.5.0
pkgrel=2
pkgdesc="Provides a simple event system"
arch=('any')
license=('Zope-2.1')
url='https://github.com/zopefoundation/zope.event'
makedepends=('python-setuptools' 'tauthon-setuptools')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/zopefoundation/zope.event/archive/${pkgver}.tar.gz")
sha512sums=('2414a283988dc646e48153e389688b8eec4db528f7ac9ff45f982ce42295d390985825ac0f9db566fc5600fe4c96a8297a9c5718a16abc6d1831c72ee42c163d')

prepare() {
  cp -a ${_pkgname}-${pkgver}{,-tauthon}
}

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  python setup.py build

  cd "${srcdir}/${_pkgname}-${pkgver}-tauthon"
  tauthon setup.py build
}

package_python-zope-event() {
  pkgdesc+=" for Python"
  depends=('python')

  cd "$srcdir/$_pkgname-$pkgver"
  python setup.py install --root="$pkgdir/" --optimize=1
  install -Dm644 LICENSE.txt -t $pkgdir/usr/share/licenses/$pkgname
}

package_tauthon-zope-event() {
  pkgdesc+=" for Tauthon"
  depends=('tauthon')

  cd "${srcdir}/$_pkgname-${pkgver}-tauthon"
  tauthon setup.py install --root="$pkgdir/" --optimize=1
  install -Dm644 LICENSE.txt -t $pkgdir/usr/share/licenses/$pkgname
}