# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=python-wxpython
_pkgname=wxPython
pkgver=4.0.7.2
_pkgver="${pkgver%.*}"
_post="${pkgver##*.}"
pkgrel=2
pkgdesc="Cross-platform GUI toolkit"
arch=('i686' 'x86_64')
license=('wxWindows-Library-3.1')
url='https://www.wxpython.org'
depends=('wxgtk3' 'python-six')
makedepends=('mesa' 'glu' 'webkitgtk' 'python-requests' 'python-setuptools')
source=("https://files.pythonhosted.org/packages/source/w/wxPython/wxPython-$_pkgver.post$_post.tar.gz")
sha512sums=('7af89db90a0f7e6b644d61c1ede01ec36a2c295e46d44692ae9dbc4af923310c1b498a52f45b02a89e8917d844c6abe67e5f3fdd9c1d51da3312899319a349e4')

prepare() {
  sed -i "s|WX_CONFIG = 'wx-config'|WX_CONFIG = 'wx-config-gtk3'|" $_pkgname-$_pkgver.post$_post/build.py
}

build() {
  cd "$_pkgname-$_pkgver.post$_post"

  python build.py build --use_syswx --release
}

package() {
  cd "$_pkgname-$_pkgver.post$_post"

  python build.py install --destdir="$pkgdir"

  install -Dm644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
  find "$pkgdir/usr/lib" -type f | xargs chmod 644
}