# Maintainer: Jesus E. <heckyel@riseup.net>

_name=vobject
pkgname=python-vobject
pkgver=0.9.6.1
_debver=0.9.6.1
_debrel=0.2
pkgrel=1
pkgdesc='Module for parsing and generating vCard and vCalendar files'
url='https://eventable.github.io/vobject/'
license=('Apache-2.0')
arch=('any')
depends=('python-dateutil')
makedepends=('python-setuptools' 'quilt')
source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/python-vobject/python-vobject_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('0b299fd4ca105a063f4ac7b03b157c54a3867d6fb798f9072897939b0ba275ba0887bb001c5ed38002a8eb1c10aee710af880413c072140b855af4b62d5aff72'
            'c422992afb8337411eb6853fe50d3ae3534dd47425ee1b7911be30490faee9d1672fa6b36a9ed95705c7fd5e2077204d01007c078bf4c31ad3423da770e3452b')

prepare() {
  cd "${_name}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${_name}-${pkgver}"
  python setup.py build
}

package() {
  cd "${_name}-${pkgver}"
  python setup.py install --skip-build \
    --optimize=1 \
    --prefix=/usr \
    --root="${pkgdir}"
  install -vDm 644 {ACKNOWLEDGEMENTS.txt,README.md} \
    -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -Dm644 LICENSE-2.0.txt -t "$pkgdir"/usr/share/licenses/$pkgname
}