# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=python-sphinx
pkgver=3.0.3
pkgrel=2
pkgdesc="Python documentation generator"
arch=('any')
url='https://www.sphinx-doc.org/'
license=('Simplified-BSD')
depends=('python-babel'
         'python-docutils'
         'python-imagesize'
         'python-jinja'
         'python-pygments'
         'python-requests'
         'python-setuptools'
         'python-snowballstemmer'
         'python-sphinx-alabaster-theme'
         'python-sphinxcontrib-'{{apple,dev,html}help,jsmath,qthelp,serializinghtml})
optdepends=('graphicsmagick: for ext.imgconverter')
source=("https://pypi.org/packages/source/S/Sphinx/Sphinx-$pkgver.tar.gz")
sha512sums=('1e37224d04f0a7836a7132cea55c67b9d15a22f941a790288438b39d455973f254205ffd1e99e6e2305430725a6a623b9a85fb95b495a9f6f912fb94825fdcd0')

build() {
  cd Sphinx-$pkgver
  make build
}

package() {
  cd Sphinx-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname LICENSE
}