# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-setuptools
pkgname=('python-setuptools' 'tauthon-setuptools')
pkgver=44.1.1
_debver=$pkgver
_debrel=1
pkgrel=3
arch=('any')
license=('Expat')
url='https://pypi.python.org/pypi/setuptools'
makedepends=('python-packaging' 'tauthon-packaging' 'python-appdirs' 'tauthon-appdirs' 'quilt')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/pypa/setuptools/archive/v$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/python-setuptools/python-setuptools_$_debver-$_debrel.debian.tar.xz")
sha512sums=('aabddfbd62b95ce7d8e68d582362361d32b91e65e6d00c393593521a2c1c383552e324ae64974049ae9880072c8741e2393e6482cd07ff7dd30615e91e9e1450'
            '24353f22c424955e593c2a7077ce930b2feeca39480bcffde57775d6720cd58e22d9111491bddcb32fa9fe8482ff99542c18ab36b85c72e0580c53058b5048fe')

prepare() {
  pushd "$srcdir"/setuptools-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/install-layout.diff || true
    rm -v debian/patches/multiarch-extname.diff || true
    rm -v debian/patches/no-SOURCES.txt-in-egg-ingo.diff || true
    rm -v debian/patches/reproducible.diff || true

    quilt push -av
  fi
  popd

  # don't download and install deps
  sed -i '/pip.main(args)/d' setuptools-$pkgver/bootstrap.py

  # remove post-release tag since we are using stable tags
  sed -e '/tag_build = .post/d' \
      -e '/tag_date = 1/d' \
      -i setuptools-$pkgver/setup.cfg

  cp -a setuptools-$pkgver{,-tauthon}

  cd "$srcdir"/setuptools-$pkgver
  sed -i -e "s|^#\!.*/usr/bin/env python|#!/usr/bin/env python3|" setuptools/command/easy_install.py

  cd "$srcdir"/setuptools-$pkgver-tauthon
  sed -i -e "s|^#\!.*/usr/bin/env python|#!/usr/bin/env tauthon|" setuptools/command/easy_install.py

  export SETUPTOOLS_INSTALL_WINDOWS_SPECIFIC_FILES=0
}

build() {
  cd "$srcdir"/setuptools-$pkgver
  python bootstrap.py
  python setup.py build

  cd "$srcdir"/setuptools-$pkgver-tauthon
  tauthon bootstrap.py
  tauthon setup.py build
}

package_python-setuptools() {
  pkgdesc="Easily download, build, install, upgrade, and uninstall Python packages"
  depends=('python-packaging' 'python-appdirs')

  cd "$srcdir"/setuptools-$pkgver
  python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1 --skip-build

  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
}

package_tauthon-setuptools() {
  pkgdesc="Easily download, build, install, upgrade, and uninstall Tauthon packages"
  depends=('tauthon-packaging' 'tauthon-appdirs')

  cd "$srcdir"/setuptools-$pkgver-tauthon
  tauthon setup.py install --prefix=/usr --root="$pkgdir" --optimize=1 --skip-build
  rm "$pkgdir"/usr/bin/easy_install

  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname
}