# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=python-pyqt
_pkgname=PyQt5
pkgdesc="A set of Python bindings for the Qt5 toolkit"
pkgver=5.15.2
pkgrel=6
arch=('i686' 'x86_64')
url='https://riverbankcomputing.com/software/pyqt/intro'
license=('GPL-3')
depends=('python-pyqt-sip' 'qt-base')
optdepends=(#'python-opengl: enable OpenGL 3D graphics in PyQt applications'
            'qt-declarative: QtQml, qmlplugin'
            'qt-multimedia: QtMultimedia, QtMultimediaWidgets'
            'qt-sensors: QtSensors'
            #'qt-serialport: QtSerialPort'
            #'qt-speech: QtTextToSpeech'
            'qt-svg: QtSvg'
            'qt-tools: QtHelp, QtDesigner'
            'qt-webchannel: QtWebChannel'
            'qt-webkit: QtWebKit, QtWebKitWidgets'
            'qt-websockets: QtWebSockets'
            'qt-x11extras: QtX11Extras'
            'qt-xmlpatterns: QtXmlPatterns')
makedepends=('sip' 'pyqt-builder' 'python-setuptools'
             #'qt-declarative' # already as depends
             'qt-multimedia'
             #'qt-sensors' # already as depends
             'qt-svg'
             'qt-tools'
             #'qt-webchannel' # already as depends
             'qt-webkit'
             'qt-websockets'
             'qt-x11extras'
             'qt-xmlpatterns')
provides=(qt-python-bindings)
conflicts=('pyqt-common')
source=("https://pypi.python.org/packages/source/${_pkgname::1}/$_pkgname/$_pkgname-$pkgver.tar.gz")
sha512sums=('6d48d2ed907b436131d46b0513d82e1069c76e873d395e4a6c0832ae3a20621b92d3abece046c5fcd14cb818d50ffb369153fca1ce9341f0db1b8c479b94e621')

prepare() {
  mkdir build
}

build() {
  cd build
  msg "configure.py is running, but doesn't print anything, please see in top (or htop) command"
  python -d -v $srcdir/$_pkgname-$pkgver/configure.py \
    --confirm-license \
    --debug \
    --qsci-api \
    --qsci-api-destdir /usr/share/qt/qsci/api/python \
    --verbose
  make
}

package() {
  make INSTALL_ROOT="$pkgdir" -C build install -j1

  # Remove unused py2 version of uic modules:
  rm -r "$pkgdir"/usr/lib/python*/site-packages/$_pkgname/uic/port_v2

  # Compile Python bytecode
  python -m compileall -d / "$pkgdir"/usr/lib
  python -O -m compileall -d / "$pkgdir"/usr/lib

  # License
  install -Dm644 $_pkgname-$pkgver/LICENSE -t ${pkgdir}/usr/share/licenses/$pkgname
}