# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=python-pyqt-sip
_pkgname=PyQt5_sip
pkgver=12.8.1
_debname=pyqt5-sip
_debver=$pkgver
_debrel=1
pkgrel=2
arch=('i686' 'x86_64')
pkgdesc='The sip module support for PyQt'
url='https://riverbankcomputing.com/software/pyqt/intro'
license=('LGPL-3')
depends=('python')
makedepends=('python-setuptools')
source=(https://pypi.python.org/packages/source/${_pkgname::1}/${_pkgname/_/-}/$_pkgname-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/${pkgname::1}/$_debname/${_debname}_$_debver-$_debrel.debian.tar.xz)
sha512sums=('42c739d602dbf7d18b4381e3dd61c72165fc49e7e8723430f452029b10a27cf04f2c2ed482fed055432bffda80f7746c6aa61ec1a0ef015661dc5575f96b3cda'
            'ecc39a48930503c73b6d280e786a73af86645d8418da78e6e7395139e723cab69296a3c19ab842136d4fe79076c20bf4468598fb6cd9169dcde7b52c6e159957')

prepare() {
  cd $_pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    mv "$srcdir"/debian .
  fi
}

build() {
  cd $_pkgname-$pkgver
  python setup.py build
}

package()  {
  cd $_pkgname-$pkgver
  python setup.py install --root="$pkgdir"
  install -Dm644 debian/copyright -t ${pkgdir}/usr/share/licenses/${pkgname}
}