# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-pyopenssl
pkgname=('python-pyopenssl' 'tauthon-pyopenssl')
pkgver=20.0.1
_debver=$pkgver
_debrel=1
pkgrel=1
arch=('any')
url='https://github.com/pyca/pyopenssl'
license=('Apache-2.0')
makedepends=('libressl' 'python-setuptools' 'tauthon-setuptools' 'python-cryptography'
             'tauthon-cryptography' 'python-six' 'tauthon-six' 'quilt')
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/pyca/pyopenssl/archive/${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/p/pyopenssl/pyopenssl_${_debver}-${_debrel}.debian.tar.xz)
sha512sums=('cfaea0ed9d98675ad263c71b0d3b1572224baecd69261653b78a1801203168f61025bce35c94606217354e3c93aea5dc77fda4410e6559fed022fec00982aac8'
            '8da3ff05e3cdb49b69db0ee68bdcbb130842024427c26bd5c905b9a04e783e6858a6fc57ba40992cd4fe2e17d35e5a53f3f3891c0d3a22d934b51f82ff9caccf')

prepare() {
  cd "$srcdir"/pyopenssl-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/0002-pass-PYTHONPATH-when-building-HTML-doc.patch || true

    quilt push -av
  fi
  cd $srcdir
  cp -a pyopenssl-$pkgver{,-tauthon}
  export LC_CTYPE=en_US.UTF-8
}

build() {
  cd "$srcdir"/pyopenssl-$pkgver
  python setup.py build

  cd "$srcdir"/pyopenssl-$pkgver-tauthon
  tauthon setup.py build
}

package_python-pyopenssl() {
  pkgdesc="Python wrapper module around the LibreSSL library"
  depends=('libressl' 'python' 'python-six' 'python-cryptography')

  cd pyopenssl-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE -t $pkgdir/usr/share/licenses/$pkgname
}

package_tauthon-pyopenssl() {
  pkgdesc="Tauthon wrapper module around the LibreSSL library"
  depends=('libressl' 'tauthon' 'tauthon-six' 'tauthon-cryptography')

  cd pyopenssl-$pkgver-tauthon
  tauthon setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE -t $pkgdir/usr/share/licenses/$pkgname
}