# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-pycryptodome
pkgname=('python-pycryptodome' 'tauthon-pycryptodome')
pkgver=3.9.7
_debver=$pkgver
_debrel=1
pkgrel=2
license=('Simplified-BSD')
arch=('i686' 'x86_64')
url='https://www.pycryptodome.org/'
makedepends=('gmp' 'python-setuptools' 'tauthon-setuptools' 'quilt')
source=("pycryptodome-${pkgver}.tar.gz::https://github.com/Legrandin/pycryptodome/archive/v${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/pycryptodome/pycryptodome_$_debver+dfsg1-$_debrel.debian.tar.xz")
sha512sums=('3b0361d7afc772d9dec068b42d6a36732faeec55b7317cbe31fa86d65069b314c735fcfce03e68381d86f64dcb7abd751b0225c05f760631266063c1664fca4c'
            '16d7aca683119131afeb7947d858fdac97c4ffec6fb943deda8c62907eb4afb4292c514bf51cbfdaa418b3525c6dc81945f328b297d8f0a530df9ba470208bf3')

prepare() {
  cd "$srcdir/pycryptodome-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  cp -a "$srcdir/pycryptodome-$pkgver"{,-tauthon}
}

build() {
  cd "$srcdir/pycryptodome-$pkgver"
  python setup.py build

  cd "$srcdir/pycryptodome-$pkgver-tauthon"
  tauthon setup.py build
}

package_python-pycryptodome() {
  pkgdesc="Collection of cryptographic algorithms and protocols, implemented for use from Python"
  depends=('python' 'gmp')
  conflicts=('python-crypto')
  provides=('python-crypto')
  replaces=('python-crypto')

  cd "pycryptodome-$pkgver"
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE.rst -t "$pkgdir/usr/share/licenses/$pkgname"

  rm -r "$pkgdir"/usr/lib/python3.*/site-packages/Crypto/SelfTest/
}

package_tauthon-pycryptodome() {
  pkgdesc="Collection of cryptographic algorithms and protocols, implemented for use from Tauthon"
  depends=('tauthon' 'gmp')
  conflicts=('tauthon-crypto')
  provides=('tauthon-crypto')
  replaces=('tauthon-crypto')

  cd "pycryptodome-$pkgver-tauthon"
  tauthon setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE.rst -t "$pkgdir/usr/share/licenses/$pkgname"

  rm -r "$pkgdir"/usr/lib/tauthon2.*/site-packages/Crypto/SelfTest/
}