# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-psutil
pkgname=('python-psutil' 'tauthon-psutil')
pkgver=5.8.0
_debver=$pkgver
_debrel=1
pkgrel=1
arch=('i686' 'x86_64')
url='https://github.com/giampaolo/psutil'
license=('Modified-BSD')
makedepends=('python' 'python-setuptools' 'tauthon' 'tauthon-setuptools' 'quilt')
source=("https://github.com/giampaolo/psutil/archive/release-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/python-psutil/python-psutil_$_debver-$_debrel.debian.tar.xz")
sha512sums=('156dffb660fcfb23b420d0455296c6b1ab366844390706af40788d89335eb946bb2e66f792755071c09ca282ad0d5503bb62175344753c88ba35613756e22fa3'
            '327e793281bc4c29962315d6af2e272a91f2960e7dba31abac5b8a15a7f8bad9bf9bf9bb4408d5f3bff3a2f1e325d7fddfe1c2ae851dd85a0cadad361b4e2c06')

prepare() {
  cd psutil-release-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd psutil-release-$pkgver

  python setup.py build --build-lib=build/python

  tauthon setup.py build --build-lib=build/tauthon
  find build/tauthon -type f -exec \
    sed -i '1s,^#! \?/usr/bin/\(env \|\)python$,#!/usr/bin/tauthon,' {} \;
}

package_python-psutil() {
  pkgdesc='A cross-platform process and system utilities module for Python'
  depends=('python')

  cd psutil-release-$pkgver
  python setup.py build --build-lib=build/python \
                  install --root="$pkgdir" --optimize=1
  install -D -m 644 LICENSE "$pkgdir/"usr/share/licenses/$pkgname/LICENSE
}

package_tauthon-psutil() {
  pkgdesc='A cross-platform process and system utilities module for Tauthon'
  depends=('tauthon')

  cd psutil-release-$pkgver
  tauthon setup.py build --build-lib=build/tauthon \
                   install --root="$pkgdir" --optimize=1
  install -D -m 644 LICENSE "$pkgdir/"usr/share/licenses/$pkgname/LICENSE
}