# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-ply
pkgname=('python-ply' 'tauthon-ply')
pkgver=3.11
_debver=$pkgver
_debrel=5
pkgrel=2
pkgdesc="Implementation of lex and yacc parsing tools"
arch=('any')
url='https://www.dabeaz.com/ply/'
license=('Modified-BSD')
makedepends=('python-setuptools' 'tauthon-setuptools' 'quilt')
source=("ply-$pkgver.tar.gz::https://github.com/dabeaz/ply/archive/refs/tags/$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/ply/ply_$_debver-$_debrel.debian.tar.xz")
sha512sums=('c36e4ea0eb5bb7cca8cc34aa62dd711be755e44f1336a0093d7c9c1ea4d5d8cae8316416a2109ba24bb2b71f7a971b0b34a7ea45c43d4c7c63c513156945fc17'
            'ac3ac2f9fa58f74716ee3871a7998e4b76ee4542dc09774193b95a7bcd13c2520556576dc8cc1d68b215fb22fc85ae064bd5812fa6dc7514565dcf97640722d1')

prepare() {
  cd ply-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  cd $srcdir
  cp -a ply-$pkgver{,-tauthon}
}

package_python-ply() {
  depends=('python')

  cd "ply-$pkgver"
  python setup.py install --root="$pkgdir"

  install -Dm644 debian/copyright -t "$pkgdir/usr/share/licenses/$pkgname"
}

package_tauthon-ply() {
  depends=('tauthon')

  cd "ply-$pkgver-tauthon"
  tauthon setup.py install --root="$pkgdir"

  install -Dm644 debian/copyright -t "$pkgdir/usr/share/licenses/$pkgname"
}