# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-nose
pkgname=('python-nose' 'tauthon-nose')
pkgver=1.3.7
_debver=$pkgver
_debrel=9
pkgrel=5
pkgdesc="A discovery-based unittest extension"
arch=('any')
url='https://readthedocs.org/docs/nose/'
license=('LGPL-2.1')
makedepends=('python' 'python-setuptools' 'tauthon' 'tauthon-setuptools' 'quilt')
source=("nose-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/n/nose/nose_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/n/nose/nose_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('e65c914f621f8da06b9ab11a0ff2763d6e29b82ce2aaed56da0e3773dc899d9deb1f20015789d44c65a5dad7214520f5b659b3f8d7695fb207ad3f78e5cf1b62'
            '5adbd16b0a8c516c497dbc1b1f9f6b6ea24aaa067f7c8e9762d6df02e9b4f7a7721935aaf29565483a0e9013db6a1c4ed4b34baaee790523151d1ab55571a039')

prepare() {
  cd "$srcdir/nose-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/2to3-fixups.diff || true
    rm -v debian/patches/docs-sys.path.diff || true
    rm -v debian/patches/no-distribute_setup.diff || true
    rm -v debian/patches/no-install-data.diff || true

    quilt push -av
  fi
}

build() {
  cd "$srcdir/nose-$pkgver"
  sed -i -e "s:man/man1:share/man/man1:g" setup.py
  cp -R "$srcdir/nose-$pkgver" "$srcdir/nose-$pkgver-tauthon"
}

package_python-nose() {
  pkgdesc+=" (for Python)"
  depends=('python' 'python-setuptools')
  cd "$srcdir/nose-$pkgver"
  python setup.py install --prefix=/usr --root="${pkgdir}"
  install -Dm644 lgpl.txt -t $pkgdir/usr/share/licenses/$pkgname
}

package_tauthon-nose() {
  pkgdesc+=" (for Tauthon)"
  depends=('tauthon' 'tauthon-setuptools')
  cd "$srcdir/nose-$pkgver-tauthon"
  tauthon setup.py install --prefix=/usr --root="${pkgdir}"
  mv "$pkgdir/usr/bin/nosetests" "$pkgdir/usr/bin/nosetests-tauthon"
  rm -rf "$pkgdir/usr/share"
  install -Dm644 lgpl.txt -t $pkgdir/usr/share/licenses/$pkgname
}