# Maintainer: Jesus E. <heckyel@riseup.net>

_name=mutagen
pkgname=python-mutagen
pkgver=1.45.1
_debver=1.45.1
_debrel=2
pkgrel=1
arch=('any')
pkgdesc='An audio metadata tag reader and writer (python library)'
url='https://github.com/quodlibet/mutagen'
license=('GPL-2')
depends=('python-setuptools')
makedepends=('quilt')
source=("https://github.com/quodlibet/${_name}/releases/download/release-$pkgver/${_name}-$pkgver.tar.gz"{,.sig}
        "https://deb.debian.org/debian/pool/main/m/mutagen/mutagen_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('c5244efa01b9de5ec22ceca39e55f34b933ca4a5bec0f2088fd3adca657f0230cbe85cd5e156db1d90fb44d9339bc94dc3bdcd3e49f1b0d46bc3d71ece6b45d8'
            'SKIP'
            '20a621ac9be007623a9996cd8f26294d6609321e631fc14facf1e21c7c0fbc2edfc5e743d34ddd37891ebb2ef5223de310a6b84d7782c32f4b0a3767d7e291b7')
validpgpkeys=('0EBF782C5D53F7E5FB02A66746BD761F7A49B0EC') # Christoph Reiter <reiter.christoph@gmail.com>

prepare() {
  mv -v "${_name}-$pkgver" "${pkgname}-${pkgver}"

  cd "${pkgbase}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${pkgbase}-${pkgver}"
  python setup.py build
}

package() {
  cd "${pkgbase}-${pkgver}"
  python setup.py install --skip-build \
                          --optimize=1 \
                          --prefix=/usr \
                          --root="${pkgdir}"
  install -vDm 644 {NEWS,README.rst} \
    -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
}