# Maintainer: Jesus E. <heckyel@riseup.net>

_pkgname=jsmin
pkgbase=python-$_pkgname
pkgname=(python-$_pkgname tauthon-$_pkgname)
pkgver=3.0.1
pkgrel=1
pkgdesc="JavaScript minifier"
arch=('any')
url='https://pypi.org/pypi/jsmin'
license=('Expat')
makedepends=('python-setuptools' 'tauthon-setuptools')
source=("https://pypi.org/packages/source/${_pkgname:0:1}/$_pkgname/$_pkgname-$pkgver.tar.gz")
sha512sums=('f65ead107ffcda67bbea1aea2070d1012139043cd1094d95c0393b1370e2e11a6c6e09af2f3af6f32ab0acc35fd702431954175d930a1898a142808fc3d57b71')

prepare() {
  cp -rf "$_pkgname-$pkgver" "$_pkgname-$pkgver-tauthon"
}

build() {
  cd "$srcdir/$_pkgname-$pkgver"
  python setup.py build

  cd "$srcdir/$_pkgname-$pkgver-tauthon"
  tauthon setup.py build
}

package_python-jsmin() {
  pkgdesc+=" for Python"
  depends=('python')
  cd "$srcdir/$_pkgname-$pkgver"
  python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
  install -Dm644 LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgname"
}

package_tauthon-jsmin() {
  pkgdesc+=" for Tauthon"
  depends=('tauthon')
  cd "$srcdir/$_pkgname-$pkgver-tauthon"
  tauthon setup.py install --root="$pkgdir/" --optimize=1 --skip-build
  install -Dm644 LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgname"
}