# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=python-josepy
pkgver=1.2.0
_debver=$pkgver
_debrel=2
pkgrel=2
pkgdesc="JOSE protocol implementation in Python"
arch=('any')
url="https://github.com/certbot/josepy"
license=('Apache-2.0')
makedepends=('quilt')
depends=('python-cryptography' 'python-pyopenssl' 'python-setuptools')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/certbot/josepy/archive/refs/tags/v$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/python-josepy/python-josepy_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('25a360b3893e1c1c524440b02e0af66c6dfefd756cebdad1c27ae8a82461200448a9c8fc835747e160cbcbb63261a4f79d7765eaae5e0b19feea5bf84d5e8896'
            '9160592002caf4fee0b2fd2f5ca8e87452d8cf29f87aad531c49a12de0627054a5b36099e2b2951139066e6d0a1c6b158d0403feb7cebbaf8ac990cea034c168')

prepare() {
  cd josepy-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "${srcdir}"/debian .

    quilt push -av
  fi
}

build() {
  cd josepy-$pkgver
  python setup.py build
}

package() {
  cd josepy-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
}