# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-imagesize
pkgname=('python-imagesize' 'tauthon-imagesize')
pkgver=1.2.0
pkgrel=2
pkgdesc="Getting image size from png/jpeg/jpeg2000/gif file"
url='https://github.com/shibukawa/imagesize_py'
arch=('any')
license=('Expat')
makedepends=('python-setuptools' 'tauthon-setuptools')
source=("https://files.pythonhosted.org/packages/source/i/imagesize/imagesize-$pkgver.tar.gz")
sha512sums=('c82a7fe433064c3a60ed664bad8ce4e602c527bcf2f7c9ab9be6ed650654626d9e0907028b2b0c5a484712bc989335b2b4f66494c8d445f5043ed4c2bc519700')

build() {
  cp -r imagesize-$pkgver imagesize-$pkgver-tauthon

  cd "$srcdir"/imagesize-$pkgver
  python setup.py build

  cd "$srcdir"/imagesize-$pkgver-tauthon
  tauthon setup.py build
}

package_python-imagesize() {
  depends=('python')

  cd imagesize-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE.rst -t $pkgdir/usr/share/licenses/$pkgname
}

package_tauthon-imagesize() {
  depends=('tauthon')

  cd imagesize-$pkgver-tauthon
  tauthon setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE.rst -t $pkgdir/usr/share/licenses/$pkgname
}