# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=python-httplib2
pkgver=0.18.1
_debver=$pkgver
_debrel=3
pkgrel=1
pkgdesc='Comprehensive HTTP client library, supporting many features'
url='https://github.com/httplib2/httplib2'
license=('Expat')
arch=('any')
depends=('python' 'ca-certificates')
makedepends=('python-setuptools' 'quilt')
source=("$pkgname-$pkgver.tar.gz::https://github.com/httplib2/httplib2/archive/v$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/python-httplib2/python-httplib2_$_debver-$_debrel.debian.tar.xz")
sha512sums=('fd40417607afc4f2b225cf50a7e3f6d437ba97445e03b1568508d31228dccb8e0bc1ea82b0d8727a2df60c6b389726d22d24646660ee1359f9b50b3c5009c2f5'
            '8f1e7f76a90c67c41d8ba5af16bd79a85002c9caedcb7d236d52c0c4793c07de0ecf0fd034d53f548a6fbaaa8151af268e96dd6406374f7b719ecf1e2a85865c')

prepare() {
  cd httplib2-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/disable-pytest-cov.patch || true

    quilt push -av
  fi
}

build() {
  cd "$srcdir"/httplib2-$pkgver
  python setup.py build
}

package() {
  cd httplib2-$pkgver
  python setup.py install -O1 --root="$pkgdir"
  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
}